| # | バグ名称 (英語/日本語) | MSX2版の実態 (修正前) | 修正後の挙動・結果 | 判定 | 対応パッチ / 格納先 |
|---|---|---|---|---|---|
| 1 | Battle Order Bug (行動順の偏り) |
初期値が敵優先、シャッフル回数が17回と不足 | シャッフル回数を64回に増やし、初期配置の偏りを解消 | 対応済 | パッチ04 (BATTLE.COM) |
| 2 | Caravan Landing Bug (キャラバン着陸) |
飛空艇がオアシスに着陸可能だが、進行停止等の致命的不具合は生じない | 仕様(ショートカット)として維持し、着陸可能なまま変更なし | 除外 | 進行上の実害がないため対象外 |
| 3 | Dialogue Bug (台詞・進行フラグミス) |
オンラク老人・12賢者・4大祭壇はMSX2版で修正済(妖精の泉タイル欠落のみ残存) | SMAP.COM は変更不要で正常動作(妖精の泉のみ パッチ01-M で復元) |
解消済 | 対応不要(MSX2版で修正済。泉のみ パッチ01-M) |
| 4 | Enemy Attack Bugs (敵攻撃・属性ミス) |
敵物理攻撃は実装済だが、敵対象魔法で弱点属性が種族属性で上書き破壊される | 魔法詠唱後も敵の弱点属性バッファが保持され、武器特効・弱点判定が正常動作 | 対応済 | パッチ05 (BATTLE.COM) |
| 5 | Enemy Magic All Allies Bug (敵全体魔法で自身除外) |
敵の味方全体魔法で詠唱者スロットを意図的にスキップ | 敵の味方全体魔法(ケアルラ等)が詠唱者自身にも正常に適用 | 対応済 | パッチ02 (BATTLE.COM) |
| 6 | Enemy Poison/Regen Bug (毒ダメージ・敵再生) |
毒ダメージが味方のみかつ1ダメージ、敵リジェネレーション処理が未実装 | プレイヤー毒ダメージを2に正常化(下限1維持)、再生持ち敵(トロール等)に毎ターン2回復を適用 | 対応済 | パッチ15 (BATTLE.COM) |
| 7 | Enemy Waking Bug (敵の睡眠解除) |
最大HPと乱数(0..80)の比較により、最大HP80以上の敵が毎ターン確実に目覚める | 最大HPに関わらず、毎ターン約10%(25/256)の固定確率で目覚める判定を実行 | 対応済 | パッチ07-W (BATTLE.COM) |
| 8 | Evasion Bug (睡眠/麻痺時の回避率) |
状態異常時に命中率計算ルーチンをスキップしてRET(基礎命中値168固定) | 睡眠・麻痺時に防御側回避率が0になり、攻撃力1.25倍を反映した通常命中判定が実行 | 対応済 | パッチ10 (BATTLE.COM) |
| 9 | Healara Effectivity Bug (ヒーラ効果値) |
ヒーラ(HEL2)の効果値がラヒーラと同じ48に設定 | ヒーラの基礎効果値が適正な24に修正 | 対応済 | パッチ08 (BDATA.TBL) |
| 10 | Lost Sprites Bug (NPC初期配置ミス) |
城の女性NPCは常時表示、滝の洞窟にコウモリは未配置(ロボットのみ) | MSX2版では元から正常に表示されており、コウモリも存在しないため変更なし | 解消済 | 対応不要(MSX2版でバグなし) |
| 11-A | シェイラ効果ルーチンミス (LOK2 Effect Routine Bug) |
敵全体デバフなのに回避「上昇」ルーチンが設定されている | 回避低下ルーチンが設定され、敵全体の回避率が正常に20低下 | 対応済 | パッチ09 (BDATA.TBL) |
| 11-B | ストライ効果ルーチンミス (TMPR Effect Routine Bug) |
BDATA.TBL でセーバーと同じ効果0DH(命中+攻撃UP)が設定されている |
効果ルーチンが0BHに変更され、攻撃力のみ+14上昇 | 対応済 | パッチ11 (BDATA.TBL) |
| 11-C | ストライ・セーバー味方不発 / セーバー命中値欠落 (Temper / Saber Bug) |
味方対象時に攻撃力・命中率をバッファから読込・保存しない。またセーバーの基礎命中上昇値が0 | 味方対象時も攻撃力・命中率が読み書きされ、セーバーの命中上昇値(+10)と攻撃力(+16)が反映 | 対応済 | パッチ11 (BATTLE.COM / BDATA.TBL) |
| 11-D | デスペル敵耐性未解除 (Dispel Bug) |
デスペル成功時、敵バッファへの耐性属性書き戻しが欠落 | デスペル成功時に敵バッファの耐性属性が正常に解除・保存 | 対応済 | パッチ07 (BATTLE.COM) |
| 11-E | 敵プロテス防御ROM参照 (Protect Bug) |
MSX2版はRAM(0x3520)の敵バッファから正しく読込 |
元から正常動作(敵プロテスで防御力上昇) | 解消済 | 対応不要(MSX2版で修正済) |
| 11-F | 知性の魔法威力未反映 (Intellect Bug) |
計算ルーチンに知性を参照するコードがない | 攻撃・ディア系にINT/2、回復系にINT全量を加算(威力が知性依存で増加) | 対応済 | パッチ14 (BATTLE.COM) |
| 11-G | 複数状態異常魔法の誤表示 (Multiple Status Bug) |
付与判定は正常だが、表示優先度により「こうかが なかった」と出る | 状態異常自体は正常に付与されるため保留 | 保留 | 表示テキストのみの不整合のため保留 |
| 11-H | 敵命中率保存欠落 (Hit Rate Save Bug) |
敵対象魔法時、敵バッファへの命中率書き戻しが欠落 | スロウ等の命中率低下が敵バッファに正常に保存 | 対応済 | パッチ07 (BATTLE.COM) |
| 12 | Magic Defense Bug (魔法防御成長値異常) |
魔法防御テーブル(0x8835)が戦士+3・魔導士+2であり、加算時にジョブIDが混入して過剰成長する |
ジョブID加算バグを解消し、戦士/ナイト+2、モンク+1、スパモン+4、白/黒魔+3の成長へ適正化 | 対応済 | パッチ12 (BATTLE.COM) |
| 13 | Multiple Level Up Bug (複数レベルアップ) |
1戦闘で2回以上のレベルアップ判定ループがない | 大量経験値獲得時に必要経験値を満たす限り連続してレベルアップ | 対応済 | パッチ13 (BATTLE.COM) |
| 14 | Mute Bug (サイレス時アイテム不可) |
アイテム使用時も沈黙判定を実行 | アイテム使用時は沈黙チェックをスキップし使用可能 | 対応済 | パッチ06 (BATTLE.COM) |
| 15 | No Canoe in Item List Bug (カヌー非表示) |
カヌー入手・河川進入・アイテム一覧展開で 0xC210 が一元化 |
元から正常動作(アイテム欄にカヌーが表示) | 解消済 | 対応不要(MSX2版で修正済) |
| 16 | Running Bug (逃走判定キャラズレ) |
逃走実行者(IY)ではなく古いポインタ(IX)を参照 |
逃走を選択したキャラクター自身のレベルと運で逃走判定を実行 | 対応済 | パッチ01 (BATTLE.COM) |
| 17 | Sort Bug (戦闘後ソートで毒が末尾へ) |
状態異常0のみ生存扱いとし、毒(04)を末尾送り | 死亡・石化のみ末尾へ送り、毒状態のキャラは隊列順を維持 | 対応済 | パッチ03 (BATTLE.COM) |
| 18 | Status Attack Bug (ミス時追加効果) |
0x9698 にてヒット数0判定が実装済 |
元から正常動作(0ヒット時は追加効果不発) | 解消済 | 対応不要(MSX2版で修正済) |
| 19 | Third Enemy Palette Bug (パレットズレ) |
MSX2のVRAM直接転送仕様に変更済 | 元から正常動作(MSX2グラフィック仕様) | 非該当 | 対応不要(ハード仕様差) |
| 20 | Weapon Data Bug (武器特効不発) |
武器属性(+04H)・特効(+05H)が戦闘バッファ(+43H/+44H)に格納されず、特効判定に到達不能RETがある |
武器属性・特効が正しく読み込まれ、弱点・特効一致時に攻撃力+4・命中+40が反映 | 対応済 | パッチ05 (BATTLE.COM) |
| - | Monk Unarmed / Armorless (モンク素手・無防具仕様) |
素手攻撃力・無防具防御力が未実装。戦闘時の素手判定も IX+46H 誤参照により1〜3人目で不発・4人目で誤作動 |
素手時 攻撃力=Lv×2・ヒット数2倍・クリティカルLv×2、無防具時 防御力=Lv が全枠で動作 |
対応済 | パッチ16 (MAIN.COM / MENU.COM / BATTLE.COM) |
| - | Gaia Fairy Spring Tile (ガイアの妖精の泉) |
ガイアの町で泉タイルが通常水タイルとなり会話メッセージ不発 | 泉南側の水際(X=45〜50, Y=19)を会話判定タイル(0x3B)へ置換 | 対応済 | パッチ01-M (SUB05.MAP 展開・再圧縮) |
| - | House Save / MP Bug (コテージ等のセーブ・MP) |
セーブ前にMP全回復(最大MP->現在MP)が行われており正常。ただしコテージの文言のみFC版のまま残存 | 処理は元から正常動作(コテージ使用時のメッセージ不整合のみ パッチ01-T で補正) | 解消済 | 処理は対応不要(文言のみ パッチ01-T) |
| - | Cottage Message (コテージメッセージ整合) |
MP回復後にセーブ確認を行うMSX2版の挙動に対し、文言が「セーブしてまほうかいふくもする?」のまま | 「HPとまほうをかいふくしました!セーブもする?」へ変更し、実挙動と一致 | 改善 | パッチ01-T (MENU.COM / MENU.MSG) |
| - | Auto-Targeting (オートターゲット機能) |
選択した敵が実行前に死亡していると「ミス!」となり行動が無駄になる | ターゲット死亡時に生存敵を自動選択(オプション指定時。敵リジェネ・毒2ダメージと両立) | 拡張 | オプション (BATTLE.COM) |
| - | Startup Free Area Check (起動時フリーエリア判定) |
起動時に CTRL キーの押下でフリーエリアの確保を代用判定しており、ドライブ初期化後に押してもメモリ配置は変わらず、不足したまま起動を通過する | HIMEM (0xFC4A) が 0xDE86 以上あるかを直接判定し、不足時は元のメッセージを表示して停止 |
改善 | パッチ17 (ブートブロック) |
BATTLE.COM 実行時のメモリ空間(0x8000〜0xBFFF)および関連メインRAM0x3400 〜 0x351F 【戦闘時 味方実効バッファ】(288バイト):
パーティ4人分の戦闘パラメータ(各72バイト)。0x3520 〜 0x362D 【戦闘時 敵実効バッファ】(270バイト):
出現敵最大9体分の戦闘パラメータ(各30バイト)。0x362E 〜 0x36FF 【戦闘バッファ直後領域】(210バイト) -> 常駐領域B:
初期化時のゼロクリア(0x8C66)以降、戦闘終了まで読み書きされない領域。初期化クリア長を縮小して保護し、パッチコード群を常駐させます。
0x3700 〜 0x3FFF 【メッセージ・魔法名バッファ】:
街・戦闘のメッセージベクタおよび魔法名表示展開領域(侵食不可)。0x8000 〜 0xBC5F 【コード&固定データ領域】:
戦闘プログラム本体および固定テーブル群。0xBC60 〜 0xBCDC 【戦闘用ワークエリア】(125バイト):
コマンド入力、敵配置座標、行動順テーブル等。戦闘中常時更新。0xBCDD 〜 0xBCFF 【未使用パディング領域】(35バイト) -> 常駐領域A:
BATTLE.COM バイナリ内の空き領域。直接書き込み可能。計32バイト常駐(残り空き 3バイト)。0xBD00 〜 0xBFFF 【PSG演奏・描画ワークエリア】:
MAIN.COM 常駐のサウンド演奏ドライバ用ワーク領域。エンカウント時のディスクアクセス前にBGMは停止されるため、ロード直後はディスクから読まれたバイナリ内容が保持されます。戦闘BGM開始(0x8047)以降にワークとして上書きされます。MAIN.COM / MENU.COM 内の固定空き領域MAIN.COM 0x7FA9 〜 0x7FFF 【末尾パディング領域】(87バイト):
直前の 0x7FA4〜0x7FA8 は OPLL(MSX-MUSIC)検出用ワークとして使用されるため保護し、0x7FA9〜0x7FF6(78バイト)をモンク補正処理に使用します(残り空き 9バイト)。MENU.COM 0xA6A5 〜 0xADB8 【埋め込みメッセージ領域】(1,812 Byte):
MENU.MSG と同一のメッセージデータ一式が埋め込まれており、MENU.COM の画面表示処理(LD IX, 0A6A5H)から直接参照されます。MENU.COM 0xADBA 〜 0xADFF 【末尾パディング領域】(70バイト):
メッセージ終端 0xADB8 以降の未使用 00 領域のうち、0xADBA〜0xADF3(58バイト)をメニュー再計算時のモンク素手・無防具処理に使用します(残り空き 12バイト)。BATTLE.COM 固定配置):
パッチ07-W(敵睡眠解除判定)で生じた余剰枠(0xBA11〜0xBA1A、10バイト枠)に、8バイトにスリム化したパッチ06(アイテム沈黙チェック回避)を固定配置します。これにより常駐領域Aからパッチ06が外れ、常駐領域Aを他のパッチへ開放します。BATTLE.COM 常駐領域A(0xBCDD〜0xBCFF, 35バイト枠):
ディスク上のバイナリ(オフセット 0x3CDD〜)に直接パッチコードを格納します(実行時転送不要)。
0xBCDD〜0xBCEC)0xBCED〜0xBCFC)0xBCFD〜0xBCFF)BATTLE.COM 常駐領域B(0x362E〜0x36FF, 210バイト枠):
ディスク末尾(0xBD10〜)に実体ブロックを格納し、起動時(0x8004)に 0x362E へ LDIR 転送して常駐させます。
P_POISON (11バイト: 0x362E〜0x3638)P11_LOAD (16バイト: 0x3639〜0x3648)P13_LVUP (12バイト: 0x3649〜0x3654)P14_INTEL (40バイト: 0x3655〜0x367C)P15_REGEN (54バイト: 0x367D〜0x36B2)AUTO_TARGET (52バイト: 0x36B3〜0x36E6)0x36B3〜0x36FF) / オートターゲット時 25バイト (0x36E7〜0x36FF)0x8C66(ファイルオフセット 0x0C67)のクリア長を 0x02FF から 0x022D へ縮小し、バッファ(0x3400〜0x362D)のみをクリアして 0x362E〜0x36FF のパッチコードを保護します。0x8000 の LD (.X80C2), SP は書き換えません。SPが正規に退避された直後の 0x8004 からローダーを実行し、転送完了後に JP 7394H でフェードアウト処理へ合流します。MAIN.COM / MENU.COM 末尾空き領域の活用(固定配置):
モンクの素手攻撃力・無防具防御力は、常駐する MAIN.COM の末尾(0x7FA9〜0x7FF6, 78バイト)および MENU.COM の末尾(0xADBA〜0xADF3, 58バイト)に固定配置します。これにより BATTLE.COM 側の空き容量を消費せずに全シーンで一貫した能力値を維持します。BATTLE.COM)【ディスク内バイナリ配置 (ロード直後)】
0x8000 +----------------------------------------+
0x8000 | 8000: LD (.X80C2), SP (SP退避を保持) |
0x8004 | 8004: CALL 0BD00H (転送ローダー呼出) |
| ... |
0xBA11 +----------------------------------------+
| 固定枠: パッチ06 沈黙回避 (8バイト) |
0xBA19 +----------------------------------------+
| 未使用余白 (2バイト: 0xBA19〜0xBA1A) |
| ... |
0xBCDD +----------------------------------------+
| 常駐領域A (直接配置・転送不要, 32バイト)|
| ・パッチ07: 敵耐性・命中保存 (16バイト)|
| ・パッチ11: 味方保存 (16バイト) |
0xBCFD +----------------------------------------+
| 未使用余白 (3バイト: 0xBCFD〜0xBCFF) |
0xBD00 +----------------------------------------+
| 起動時転送ローダー (16バイト: 0xBD00〜)|
0xBD10 +----------------------------------------+
| パッチ実体データブロック (210バイト) |
| (※BGM停止状態でロード直後に転送) |
0xBE00 +----------------------------------------+
|
| 0x8004 から CALL 0BD00H を実行し、
| 0xBD10 の実体を 0x362E へ LDIR 転送
v
【戦闘実行時 (常駐配置)】
0x362E +----------------------------------------+
| 常駐領域B (210バイト枠) |
| ・プレイヤー毒2ダメージ (11B) |
0x3639 +----------------------------------------+
| ・パッチ11: 味方攻撃力・命中読込 (16B) |
0x3649 +----------------------------------------+
| ・パッチ13: 複数Lvアップループ (12B) |
0x3655 +----------------------------------------+
| ・パッチ14: 知性反映 (40B) |
0x367D +----------------------------------------+
| ・パッチ15: 敵リジェネレーション (54B) |
0x36B3 +----------------------------------------+
| [オプション指定時] |
| ・オートターゲット本体 (52B) |
0x36E7 +----------------------------------------+
| 未使用余白 (通常 77B / オプション 25B) |
0x36FF +----------------------------------------+
0x78400| ファイル内オフセット | DSK内オフセット | 変更前 | 変更後 | 対象パッチ |
|---|---|---|---|---|
0x0254 |
0x78654 |
0D |
0B |
パッチ11: ストライ効果ルーチン正常化 (攻撃力UPのみ) |
0x029C |
0x7869C |
10 |
0E |
パッチ09: シェイラ効果ルーチン正常化 (回避低下) |
0x02F9 |
0x786F9 |
30 |
18 |
パッチ08: ヒーラ効果値正常化 (48 -> 24) |
0x0390 |
0x78790 |
00 |
0A |
パッチ11: セーバー基礎命中上昇値設定 (0 -> 10) |
0x80000x18800| ファイル内オフセット | DSK内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 対象パッチ |
|---|---|---|---|---|---|
0x0004 |
0x18804 |
0x8004 |
CD 94 73 |
CD 00 BD |
起動時転送ローダー呼出 (SP保存直後) |
0x0322 |
0x18B22 |
0x8322 |
11 |
40 |
パッチ04: 行動順シャッフル回数増加 |
0x0826 |
0x19026 |
0x8826 |
46 DD 86 25 80 |
7E DD 86 25 00 |
パッチ12: MDEF加算時のジョブID混入バグ修正 |
0x0835 |
0x19035 |
0x8835 |
03 02 04 02 02 0203 02 04 02 02 02 |
02 02 01 02 03 0302 02 04 02 03 03 |
パッチ12: MDEF成長テーブル |
0x0A4E |
0x1924E |
0x8A4E |
FE 00 |
E6 03 |
パッチ03: ソート判定(比較キャラ2) |
0x0A58 |
0x19258 |
0x8A58 |
FE 00 |
E6 03 |
パッチ03: ソート判定(比較キャラ1) |
0x0C67 |
0x19467 |
0x8C67 |
FF |
2D |
戦闘バッファ初期化クリア範囲縮小 |
0x1200 |
0x19A00 |
0x9200 |
DD 7E 07 FD 77 47DD 7E 06 FD 77 46 |
DD 7E 05 FD 77 44DD 7E 04 FD 77 43 |
パッチ05: 武器属性・特効を+43H/+44Hへ格納 |
0x1228 |
0x19A28 |
0x9228 |
DD 7E 46 |
FD 7E 45 |
パッチ16: モンク素手判定をIY+45H参照へ修正 |
0x13A5 |
0x19BA5 |
0x93A5 |
10 |
12 |
パッチ05: 敵弱点属性のロード先修正 |
0x13AB |
0x19BAB |
0x93AB |
12 |
13 |
パッチ05: 敵種族属性のロード先修正 |
0x1537 |
0x19D37 |
0x9537 |
0C |
0D |
パッチ05: 特効ジャンプ先調整 |
0x1544 |
0x19D44 |
0x9544 |
C9 |
00 |
パッチ05: 特効到達不能RETのNOP化 |
0x1571 |
0x19D71 |
0x9571 |
3A 54 98 E6 30 28 142A 6B 98 54 5D CB 3CCB 1D CB 3C CB 1D CDE9 80 32 6B 98 C9 |
3A 54 98 E6 30 28 14AF 32 57 98 2A 6B 98EB CB 3A CB 1B CB 3ACB 1B 19 22 6B 98 |
パッチ10: 睡眠麻痺回避0化 (インライン) |
0x1B5C |
0x1A35C |
0x9B5C |
28 2A |
00 00 |
パッチ02: 敵全体魔法自身除外解除 |
0x1C52 |
0x1A452 |
0x9C52 |
DD 7E 13 32 16 A2 |
00 00 00 00 00 00 |
パッチ05: 敵弱点属性の種族上書き解除 |
0x33B9 |
0x1BBB9 |
0xB3B9 |
DD |
FD |
パッチ01: 逃走判定Lv(IY参照化) |
0x33C2 |
0x1BBC2 |
0xB3C2 |
DD |
FD |
パッチ01: 逃走判定運(IY参照化) |
0x3A08 |
0x1BA08 |
0xBA08 |
3E 50 CD CF 80 16 005F DD 6E 1B DD 66 1CCD E0 80 38 08 |
CD 85 50 FE 19 30 1418 0A 00 00 00 00 0000 00 00 00 00 |
パッチ07-W: 敵睡眠解除判定固定確率化 |
| ファイル内オフセット | DSK内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 呼び出し先シンボル / 対象処理 |
|---|---|---|---|---|---|
0x04EA |
0x18CEA |
0x84EA |
2B 7C B5 28 0F |
CD 2E 36 38 0F |
P_POISON: プレイヤー毒2ダメージ呼出 |
0x0504 |
0x18D04 |
0x8504 |
FD E1 DD E1 C9 |
C3 7D 36 00 00 |
P15_REGEN: 敵リジェネフック |
0x0538 |
0x18D38 |
0x8538 |
CD 4F 86 38 03 CD 7B 86 |
CD 4F 86 38 03 CD 49 36 |
P13_LVUP: 複数Lvアップループ呼出 |
0x187D |
0x1A07D |
0x987D |
CD BC 9A |
CD 11 BA |
P06_MUTE: アイテム沈黙チェック回避 |
0x1AB5 |
0x1A2B5 |
0x9AB5 |
FD 7E 07 32 06 A2 C9 |
C3 55 36 00 00 00 00 |
P14_INTEL: 知性反映フック |
0x1C0D |
0x1A40D |
0x9C0D |
3E 00 32 1A A2 C9 |
3E 00 C3 39 36 00 |
P11_LOAD: 味方攻撃力・命中率読込 |
0x1CA7 |
0x1A4A7 |
0x9CA7 |
3A 1B A2 DD 77 0C C9 |
CD DD BC DD 77 0C C9 |
P07_DISPEL: 敵耐性・命中率保存 |
0x1D00 |
0x1A500 |
0x9D00 |
3A 15 A2 DD 77 23 C9 |
CD ED BC DD 77 23 C9 |
P11_SAVE: 味方攻撃力・命中率保存 |
--auto-target 指定時)| ファイル内オフセット | DSK内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 対象機能 |
|---|---|---|---|---|---|
0x32F5 |
0x1BAF5 |
0xB2F5 |
3A CB BC FE 00 C0 FD7E 01 32 D6 BC CD 1E93 C9 |
B7 C0 FD 7E 01 32 D6BC CD B3 36 CD 1E 93C9 00 |
オートターゲット: 味方「たたかう」前フック |
0x1931 |
0x1A131 |
0x9931 |
CD EE 83 3A D6 BC 1600 5F 21 66 BC 19 7EFE FF CA D0 9D CD 139C CD 07 9D CD 71 9CC9 |
CD B3 36 DA D0 9D CDEE 83 CD 13 9C CD 079D CD 71 9C C9 00 0000 00 00 00 00 00 0000 |
オートターゲット: 味方単体魔法前フック |
0x4000| ファイル内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 対象パッチ |
|---|---|---|---|---|
0x0069 |
0x4069 |
CD 91 55 |
C3 A9 7F |
MAIN_INIT_W: 開始・ロード後モンク補正 |
0x0422 |
0x4422 |
CD 9C 4E |
C3 AF 7F |
MAIN_BTL_W: 戦闘復帰後モンク補正 |
0x3FA9〜0x3FF6 |
0x7FA9〜0x7FF6 |
00 ... (78バイト) |
MAIN_MONK 等ブロック |
パッチ16: MAIN側モンク素手・無防具補正 |
0x80000x14800)| ファイル内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 対象パッチ |
|---|---|---|---|---|
0x0D59 |
0x8D59 |
3A 44 8D DD 86 28 DD 77 20 C9 |
C3 BA AD 00 00 00 00 00 00 00 |
MENU_ATK: メニュー攻撃力再計算フック |
0x0D95 |
0x8D95 |
3A 44 8D DD 77 22 C9 |
C3 D9 AD 00 00 00 00 |
MENU_DEF: メニュー防御力再計算フック |
0x29D7 |
0xA9D7 |
C8 C9 8F 8B A5 91 C4 D7C2 6D 95 9C A8 A7 8C 8F8B A5 91 AC 96 B2 C5 |
C8 C9 9D A8 A7 8C 7B 8F8B A5 91 95 A8 95 99 C4D7 C2 6D AC 96 B2 C5 |
パッチ01-T: コテージメッセージ修正 (埋め込み, 23 Byte) |
0x2DBA〜0x2DF3 |
0xADBA〜0xADF3 |
00 ... (58バイト) |
MENU_ATK + MENU_DEF 本体 |
パッチ16: MENU側モンク素手・無防具計算 |
0x5A400〜0x5A9FF, 1,536バイト枠)| 対象マップ | 平文内置換座標 | 変更前タイルID | 変更後タイルID | 処理内容 |
|---|---|---|---|---|
SUB05.MAP |
Y=19, X=45〜50 | 0x38 等 (水際) |
0x3B (59) |
泉南側水際マス(計6マス)を会話判定タイルへ置換し再圧縮して格納 |
0x6E600(セクタ 0x0373〜0x0376)MENU.COM は内部(0xA6A5〜0xADB8)に埋め込まれた同一データを直接参照しているため、画面表示への反映は MENU.COM 側の書き換えで行われますが、ディスク内のデータ整合性を保つため MENU.MSG 側も同様に更新します。| ファイル内オフセット | DSK内オフセット | 変更前バイト列 | 変更後バイト列 | 対象パッチ |
|---|---|---|---|---|
0x0332 |
0x6E932 |
C8 C9 8F 8B A5 91 C4 D7C2 6D 95 9C A8 A7 8C 8F8B A5 91 AC 96 B2 C5 |
C8 C9 9D A8 A7 8C 7B 8F8B A5 91 95 A8 95 99 C4D7 C2 6D AC 96 B2 C5 |
パッチ01-T: コテージメッセージ修正 (23 Byte) |
0x0000〜0x13FF) に固定配置されます。0x8000 へ読み込んだ起動処理ブロック内の判定ルーチンです。| DSK内オフセット | メモリアドレス | 変更前バイト列 | 変更後バイト列 | 対象パッチ |
|---|---|---|---|---|
0x0419〜0x0439 |
0x8019〜0x8039 |
3E 06 DD E5 FD E5 FD 2A C0 FC DD21 41 01 CD 1C 00 FD E1 DD E1 CB4F C8 21 3A 80 CD D9 80 C3 6D 81 |
2A 4A FC 11 86 DE B7 ED 52 D0 213A 80 CD D9 80 C3 6D 81 00 00 0000 00 00 00 00 00 00 00 00 00 00 |
パッチ17: 起動時フリーエリア判定 (33 Byte) |
BATTLE.COM 0x8004 フック & 0xBD00 ローダー)0x8000 でスタックポインタが .X80C2 へ退避された直後の 0x8004 をフックします。0xBD10 に格納されている210バイトの実体ブロックを 0x362E へ LDIR 転送し、本来呼ばれるはずだった 0x7394(フェードアウト)へ JP で合流します。; --- 呼び出し元フック (0x8004 〜 0x8006: 3バイト) ---
8000: ED 73 C2 80 LD (.X80C2), SP ; スタックポインタ退避 (元コードのまま無変更)
8004: CD 00 BD CALL 0BD00H ; 本来の CALL 7394H を差し替え
; --- ローダー本体 (0xBD00 〜 0xBD0F: 16バイト) ---
BD00: 21 10 BD LD HL, 0BD10H ; 転送元: ファイル末尾パッチ実体ブロック
BD03: 11 2E 36 LD DE, 362EH ; 転送先: 常駐領域B (0x362E)
BD06: 01 D2 00 LD BC, 00D2H ; 転送サイズ: 210バイト
BD09: ED B0 LDIR ; 0x362E へ一括コピー
BD0B: C3 94 73 JP 7394H ; フェードアウト処理へ合流 (復帰先は 0x8007)
BD0E: 00 00 NOP NOP
0xB3B3 にて逃走実行キャラの戦闘バッファを IY に計算しているにもかかわらず、直後のレベル取得(0xB3B9)および運取得(0xB3C2)で IX(直前のキャラのポインタ)を参照しています。DD(IX)から FD(IY)へ変更します。0xB3B9: FD 7E 26 LD A, (IY+26H) ; レベル取得
0xB3C2: FD 7E 14 LD A, (IY+14H) ; 運取得
0x9B5C の JR Z, .X9B88 により、詠唱者自身のスロット番号と一致する対象への効果適用を除外しています。NOP 2個で無効化し、詠唱者自身にも全体魔法(ケアルラ等)がかかるようにします。0x9B5C: 00 00 NOP NOP
0x00(正常)のみを生存優先度 5 と判定しているため、毒(0x04)のキャラクターが死亡(0x01)や石化(0x02)と同列に扱われ、隊列の末尾に送られていました。CP 00H を AND 03H(bit 0: 死亡、bit 1: 石化のマスク)に変更します。毒(0x04)はマスク結果が 0 となり、正常キャラと同様に優先度 5 として扱われます。0x8A4E: E6 03 AND 03H
0x8A58: E6 03 AND 03H
0x11)しかないため、初期位置が前の敵に偏って先制行動が発生していました。0x40)へ増加させます。0x8322: 40 LD B, 40H
0x0800、1武器8バイト)の構造は +04H が属性、+05H が特効、+06H がグラフィックID、+07H が色・アニメとなっています。しかし戦闘バッファ初期化(0x9200〜0x920B)では +06H/+07H を (IY+46H)/(IY+47H) に格納する一方で、ダメージ計算側(0x9359/0x935F)が期待する (IY+43H)(属性)と (IY+44H)(特効)への格納処理が抜けており、常に 0 となっていました。0x938E において、特効判定ルーチン 0x9545 が .X9855 を弱点比較用、.X9856 を種族比較用として参照しているにもかかわらず、+10H(耐性)を .X9855 に、+12H(弱点)を .X9856 に格納しています。0x9544: RET により、後続の特効判定処理(0x9545〜)が到達不能になっています。0x9C13(0x9C4C〜0x9C57)において、弱点属性(+12H)を .XA216 へ読み込んだ直後、誤って種族属性(+13H)で同じアドレスを上書きしています。0x9200〜0x920B のコピー対象を武器データの +04H(属性)・+05H(特効)へ、格納先を (IY+43H)・(IY+44H) へ修正し、攻撃読込側は元の +43H/+44H 参照を維持します。+12H)を .X9855 に、種族属性(+13H)を .X9856 に格納するよう修正します。0x9537 のジャンプ先を 0x9545 へ調整し、0x9544 の RET を NOP 化して特効判定へ通過させます。0x9C52〜0x9C57(6バイト)を NOP 化し、弱点属性の上書き破壊を解除します。0x9200: DD 7E 05 LD A, (IX+05H) ; 武器特効 (+05H)
0x9203: FD 77 44 LD (IY+44H), A ; -> 戦闘バッファ (+44H)
0x9206: DD 7E 04 LD A, (IX+04H) ; 武器属性 (+04H)
0x9209: FD 77 43 LD (IY+43H), A ; -> 戦闘バッファ (+43H)
0x93A5: 12 LD A, (IY+12H) ; 敵弱点属性 -> .X9855
0x93AB: 13 LD A, (IY+13H) ; 敵種族属性 -> .X9856
0x9537: 0D JR Z, $+15 ; 特効処理(0x9545)へジャンプ
0x9544: 00 NOP ; 暗闇時も特効処理へ通過
0x9C52: 00 00 00 00 00 00 ; 種族属性による弱点上書きを解除 (NOP)
0x9871 を経由するため、沈黙判定 0x9ABC が無条件に実行されていました。0xBA11 に8バイトサブルーチンを配置し、コマンド種別(.XBCC8)がアイテム(1以上)の場合は即座に Carry=0 で復帰、魔法の場合は 0x9ABC へジャンプします。; --- 呼び出し元 (0x987D: 3バイト) ---
987D: CD 11 BA CALL 0BA11H
; --- パッチ本体 (固定枠: 0xBA11 〜 0xBA18: 8バイト) ---
BA11: 3A C8 BC LD A, (.XBCC8) ; コマンド種別取得
BA14: B7 OR A
BA15: C0 RET NZ ; アイテムなら Carry=0 で即復帰
BA16: C3 BC 9A JP 9ABCH ; 魔法なら正規沈黙チェックへ末尾ジャンプ
.X9C71 において、耐性属性(+10H)および命中率(+0BH)を敵バッファへ書き戻すコードが欠落していました。+0CH)を書き戻し、常駐領域A(0xBCDD)にて耐性属性と命中率を敵バッファへ保存します。; --- 呼び出し元 (0x9CA7 〜 0x9CAD: 7バイト) ---
9CA7: CD DD BC CALL 0BCDDH ; 耐性・命中保存サブルーチン呼出
9CAA: DD 77 0C LD (IX+0CH), A ; 攻撃力保存
9CAD: C9 RET
; --- パッチ本体 (常駐領域A: 0xBCDD 〜 0xBCEC: 16バイト) ---
BCDD: 3A 17 A2 LD A, (.XA217) ; 耐性属性
BCE0: DD 77 10 LD (IX+10H), A ; 耐性保存 (11-D)
BCE3: 3A 09 A2 LD A, (.XA209) ; 命中率
BCE6: DD 77 0B LD (IX+0BH), A ; 命中率保存 (11-H)
BCE9: 3A 1B A2 LD A, (.XA21B) ; 攻撃力をロードして復帰
BCEC: C9 RET
0xBA08 において、敵の最大HPと乱数(0〜80)を減算比較し、最大HPが乱数を上回る場合に目を覚ます処理を行っています。このため最大HPが80以上の敵は毎ターン100%確実に目覚め、睡眠状態が持続しませんでした。0x5085)により約10%(25/256、値が 0x19 未満)の固定確率で目覚めるよう差し替えます。目覚める場合は直ちに 0xBA1B(RES 5)へ直行させ、末尾の 0xBA11〜0xBA1A(10バイト)をパッチ06用の空き枠として開放します。; --- 呼び出し箇所: BATTLE.COM 0xBA08 〜 0xBA1A (19バイト枠) ---
BA08: CD 85 50 CALL 5085H ; 乱数 0..255 取得 (3バイト)
BA0B: FE 19 CP 19H ; 25/256 (約9.8%) の解除判定 (2バイト)
BA0D: 30 14 JR NC, 0BA23H ; 目覚めない場合はメッセージ表示へ (2バイト)
BA0F: 18 0A JR 0BA1BH ; 目覚める場合は RES 5 へ直行 (2バイト)
; 0xBA11 〜 0xBA1A: パッチ06 (8バイト) 配置先枠
BDATA.TBL(0x02F9)において、ヒーラ(HEL2)の効果値がラヒーラ(HEL3)と同じ 0x30(48)に設定されていました。0x18(24)に書き換えます。BDATA.TBL(0x029C)において、シェイラ(LOK2)の効果ルーチン番号が誤って味方用回避上昇ルーチン 0x10 に設定されており、敵全体の回避率を上昇させていました。0x0E に変更します。0x9571 において、防御側が睡眠・麻痺の際に攻撃力1.25倍を計算した後、直ちに RET して通常命中計算ルーチン(0x958C)をスキップしていました。このため命中率が基礎値168固定となり、高レベルでも空振りが多発していました。0x9571〜0x958B, 27バイト枠)に直接インライン実装します。防御側回避率(.X9857)を 0 クリアし、16bit精度のまま攻撃力1.25倍を計算して通常命中計算(0x958C)へ合流させます。; --- インライン実装 (0x9571 〜 0x958B: 27バイト) ---
9571: 3A 54 98 LD A, (.X9854) ; 防御側状態異常
9574: E6 30 AND 30H ; 睡眠(20H) または 麻痺(10H)?
9576: 28 14 JR Z, 958CH ; 正常なら 958CH へジャンプ
9578: AF XOR A
9579: 32 57 98 LD (.X9857), A ; 防御側回避率 = 0
957C: 2A 6B 98 LD HL, (.X986B) ; HL = 基礎攻撃力 (16bit)
957F: EB EX DE, HL ; DE = 基礎攻撃力
9580: CB 3A SRL D ; DE = 攻撃力 / 4
9582: CB 1B RR E
9584: CB 3A SRL D
9586: CB 1B RR E
9588: 19 ADD HL, DE ; HL = 攻撃力 + 攻撃力/4 = 1.25倍
9589: 22 6B 98 LD (.X986B), HL ; 実効攻撃力保存 (16bit)
; 958CH の通常命中率計算ルーチンへそのまま合流
BDATA.TBL(0x0254)において、ストライ(TMPR)の効果ルーチン番号がセーバーと同じ 0x0D(命中+攻撃力UP)に設定されていました。+20H)と命中率(+21H)をワークに読み込まず、終了後も書き戻していませんでした。BDATA.TBL(0x0254)の効果番号を 0x0B(攻撃力のみUP)へ変更します。0x9C0D)は LD A, 00H をフック元で行ってから常駐領域B(0x3639)へジャンプして味方攻撃力・命中率を読込。0x9D00)は常駐領域A(0xBCED)で攻撃力・命中率を保存し、フック元で回避率を書き戻してリターンします。; --- 読込側フック (0x9C0D 〜 0x9C12: 6バイト) ---
9C0D: 3E 00 LD A, 00H
9C0F: C3 39 36 JP 03639H
9C12: 00 NOP
; --- 読込側本体 (常駐領域B: 0x3639 〜 0x3648: 16バイト) ---
3639: 32 1A A2 LD (.XA21A), A
363C: DD 7E 20 LD A, (IX+20H) ; 味方攻撃力読込
363F: 32 1B A2 LD (.XA21B), A
3642: DD 7E 21 LD A, (IX+21H) ; 味方命中率読込
3645: 32 09 A2 LD (.XA209), A
3648: C9 RET
; --- 保存側フック (0x9D00 〜 0x9D06: 7バイト) ---
9D00: CD ED BC CALL 0BCEDH ; 保存サブルーチン呼出
9D03: DD 77 23 LD (IX+23H), A ; 回避率保存
9D06: C9 RET
; --- 保存側本体 (常駐領域A: 0xBCED 〜 0xBCFC: 16バイト) ---
BCED: 3A 1B A2 LD A, (.XA21B)
BCF0: DD 77 20 LD (IX+20H), A ; 味方攻撃力書き戻し
BCF3: 3A 09 A2 LD A, (.XA209)
BCF6: DD 77 21 LD (IX+21H), A ; 味方命中率書き戻し
BCF9: 3A 15 A2 LD A, (.XA215) ; 回避率をロードして復帰
BCFC: C9 RET
0x881C〜0x8834)において、冒頭で A レジスタにジョブID(0〜11)を読み込んだ後、0x8826 でテーブル値を B に入れ、0x8827 で A をリセットせずに ADD A, (IX+25H); ADD A, B を実行しています。このため、毎レベルアップ時に「ジョブID+テーブル値」が魔法防御に加算され、上級職や後順ジョブほど急激に上限 200 へ到達する不具合がありました。(なお 0x87ED〜0x881B の 0x8810 テーブルは命中率成長用であり、FC版と同じ正しい値が設定されています)0x8835)が「戦士+3、魔術師+2」となっていました。0x8826〜0x882A(5バイト)を LD A, (HL); ADD A, (IX+25H); NOP に変更し、ジョブIDが加算されないように修正します。0x8835 のテーブルを戦士/ナイト:2, シーフ/忍者:2, モンク:1, スパモン:4, 赤魔/赤導:2, 白魔/白導:3, 黒魔/黒導:3 に更新します。; --- 魔法防御加算部 (0x8826 〜 0x882A: 5バイト) ---
8826: 7E LD A, (HL) ; テーブル値 (MDEF成長量) を取得
8827: DD 86 25 ADD A, (IX+25H) ; 現在MDEFを加算
882A: 00 NOP
0x8538 において、1回レベルアップ処理(0x867B)を呼ぶとそのまま次キャラの判定へ抜けてしまい、累積経験値による連続レベルアップ判定が行われていませんでした。0x3649)を呼び出し、必要経験値を満たす限り CALL 867BH(LvUP)と CALL 861BH(IX再取得)を連続実行して必要経験値未達になるまでループします。; --- 呼び出し元 (0x8538 〜 0x853F: 8バイト) ---
8538: CD 4F 86 CALL 864FH ; 1回目の経験値判定
853B: 38 03 JR C, 8540H ; 未達なら次キャラへ
853D: CD 49 36 CALL 03649H ; 連続LvUPサブルーチン呼出
; --- パッチ本体 (常駐領域B: 0x3649 〜 0x3654: 12バイト) ---
3649: CD 7B 86 CALL 867BH ; レベルアップ処理
364C: CD 1B 86 CALL 861BH ; IXポインタ再取得
364F: CD 4F 86 CALL 864FH ; 次Lv必要経験値判定
3652: 30 F5 JR NC, 3649H ; 達成中ならループ
3654: C9 RET ; 未達になったら復帰
0x9AB5)をフックし、常駐領域B(0x3655)で処理します。IX が保持されているため、知性を (IX+12H) から直接取得します。01H)またはアンデッド攻撃魔法(ディア系: 02H)の場合は知性の半分(INT / 2)を加算します。07H)の場合は原典仕様に準拠して知性の全量(INT、攻撃魔法の2倍ボーナス)を魔法基礎威力(.XA200)に加算します。; --- 呼び出し元 (0x9AB5 〜 0x9ABB: 7バイト) ---
9AB5: C3 55 36 JP 03655H
9AB8: 00 00 00 00 NOP NOP NOP NOP
; --- パッチ本体 (常駐領域B: 0x3655 〜 0x367C: 40バイト) ---
3655: FD 7E 07 LD A, (IY+07H)
3658: 32 06 A2 LD (.XA206), A ; 元処理
365B: 3A C8 BC LD A, (.XBCC8) ; コマンド種別
365E: B7 OR A
365F: C0 RET NZ ; アイテムなら即RET
3660: 3A D5 BC LD A, (.XBCD5) ; 詠唱者スロット
3663: D6 80 SUB 80H ; 味方判定 (80H〜83H -> 0〜3)
3665: D8 RET C ; 敵なら即RET
3666: DD 46 12 LD B, (IX+12H) ; B = 知性値 (戦闘バッファから直接取得)
3669: 3A 03 A2 LD A, (.XA203) ; 魔法効果タイプ
366C: 21 00 A2 LD HL, 0A200H ; 基礎威力バッファ
366F: FE 07 CP 07H ; 回復魔法?
3671: 28 06 JR Z, .HEAL ; 回復なら全量加算へ
3673: 3D DEC A
3674: FE 02 CP 02H ; 攻撃魔法(1) または ディア系(2)?
3676: D0 RET NC ; 補助魔法なら即RET
3677: CB 38 SRL B ; 攻撃魔法は INT / 2
.HEAL:
3679: 7E LD A, (HL) ; 基礎威力
367A: 80 ADD A, B ; 威力加算
367B: 77 LD (HL), A
367C: C9 RET
0x84EB: DEC HL で1ダメージしか引かれていませんでした。0x362E)を呼び出し、HP-2減算しつつ元HPが1または2の場合でも安全にHP=1を維持します。; --- 呼び出し元 (0x84EA 〜 0x84EE: 5バイト) ---
84EA: CD 2E 36 CALL 0362EH ; 毒2ダメージサブルーチン呼出
84ED: 38 0F JR C, 084FEH ; Carry=1 (元HP=1) なら書き戻しスキップ
; --- パッチ本体 (常駐領域B: 0x362E 〜 0x3638: 11バイト) ---
362E: 2B DEC HL ; HP - 1
362F: 7C LD A, H
3630: B5 OR L
3631: 37 SCF
3632: C8 RET Z ; 元HP=1なら Carry=1 で復帰 (書き戻しスキップ)
3633: 2B DEC HL ; HP - 2 (元HP>=2)
3634: 7C LD A, H
3635: B5 OR L
3636: C8 RET NZ ; 元HP>=3ならそのまま復帰 (Carry=0)
3637: 23 INC HL ; 元HP=2なら HL=1 に補正
3638: C9 RET ; Carry=0 で復帰
0x80 = 再生)を持つモンスター(トロール、キメラ等)のHP回復処理が実装されていませんでした。0x8504)をフックし、常駐領域B(0x367D)で敵スロット(0〜8)を走査。種族属性 bit 7(再生)を持つ生存敵のHPを +2 回復(最大HPを超えないようクリッピング)します。; --- 呼び出し元 (0x8504 〜 0x8508: 5バイト) ---
8504: C3 7D 36 JP 0367DH
8507: 00 00 NOP NOP
; --- パッチ本体 (常駐領域B: 0x367D 〜 0x36B2: 54バイト) ---
367D: DD 21 20 35 LD IX, 3520H ; 敵バッファ先頭
3681: 06 09 LD B, 09H ; 9体ループ
.LOOP:
3683: DD 7E 13 LD A, (IX+13H) ; 種族属性
3686: 07 RLCA ; bit 7 (再生) を Carry へ
3687: 30 1E JR NC, .NEXT ; 再生なしなら即スキップ
3689: DD 6E 04 LD L, (IX+04H) ; 現在HP読込
368C: DD 66 05 LD H, (IX+05H)
368F: 7C LD A, H
3690: B5 OR L
3691: 28 14 JR Z, .NEXT ; 未出現/死亡はスキップ
3693: 23 INC HL ; HP + 2
3694: 23 INC HL
3695: DD 5E 1B LD E, (IX+1BH) ; 最大HP読込
3698: DD 56 1C LD D, (IX+1CH)
369B: CD F0 80 CALL 80F0H ; HL > DE 判定
369E: 38 01 JR C, .SAVE ; HL <= DE ならクリッピング不要
36A0: EB EX DE, HL ; 最大HPでクリッピング
.SAVE:
36A1: DD 75 04 LD (IX+04H), L ; HP書き戻し
36A4: DD 74 05 LD (IX+05H), H
.NEXT:
36A7: 11 1E 00 LD DE, 001EH ; 次の敵スロット (+30バイト)
36AA: DD 19 ADD IX, DE
36AC: 10 D5 DJNZ .LOOP
36AE: FD E1 POP IY ; レジスタ復帰 (元処理)
36B0: DD E1 POP IX
36B2: C9 RET
BATTLE.COM 素手ヒット数2倍&クリティカル Lv×2 (0x9228)0x921E〜0x9245 にモンク/スーパーモンク用の戦闘初期化処理がありますが、0x9228 で戦闘バッファ IY ではなくパーティデータ IX(+46H)を参照しています。このため 1〜3 人目のモンクは次キャラの名前文字等を読んで素通りし、4人目のモンクだけ後続ワーク 0xC106 が 0 のときに武器装備時でも誤作動していました。0x9228 を FD 7E 45(LD A, (IY+45H))に変更します。全40種類の武器はクリティカル率 +02H が 1 以上であり、素手時のみ (IY+45H) == 0 となるため、1〜4人目のいずれでも素手時のみヒット数2倍・クリティカル率 Lv×2 が実行されます。; --- BATTLE.COM 0x9228 〜 0x922A (3バイト) ---
9228: FD 7E 45 LD A, (IY+45H) ; クリティカル率 (武器あり>=1, 素手==0)
MAIN.COM 開始後・戦闘復帰後モンク補正 (0x4069, 0x4422, 0x7FA9〜0x7FF6)MAIN.COM および BATTLE.COM のレベルアップ処理(0x867B)において、モンクの素手攻撃力(Lv×2)や無防具防御力(Lv)が計算されません(なお BATTLE.COM 0x88EF〜0x8A14 の再計算ルーチンは未呼出です)。+20H)が +1 され、防具なし防御力(+22H)も更新されません。MAIN.COM 末尾の空き領域 0x7FA9〜0x7FF6(78バイト)にパーティ4人分の補正サブルーチンを配置し、ゲーム開始・ロード直後(0x4069)および戦闘終了復帰直後(0x4422)から呼び出します。; --- 呼び出し元 ---
4069: C3 A9 7F JP 7FA9H ; 開始・ロード後ラッパーへ (元: CALL 5591H)
4422: C3 AF 7F JP 7FAFH ; 戦闘復帰後ラッパーへ (元: CALL 4E9CH)
; --- MAIN.COM 末尾配置 (0x7FA9 〜 0x7FF6: 78バイト) ---
7FA9: CD B5 7F CALL 7FB5H ; (.MAIN_INIT_W) 開始後補正
7FAC: C3 91 55 JP 5591H ; 元処理へ合流
7FAF: CD B5 7F CALL 7FB5H ; (.MAIN_BTL_W) 戦闘後補正
7FB2: C3 9C 4E JP 4E9CH ; 元処理へ合流
7FB5: DD 21 00 C0 LD IX, 0C000H ; (.MAIN_MONK) パーティ先頭
7FB9: 06 04 LD B, 04H
.P_LP:
7FBB: DD 7E 00 LD A, (IX+00H) ; ジョブID
7FBE: FE 02 CP 02H ; モンク
7FC0: 28 04 JR Z, .IS_MONK
7FC2: FE 08 CP 08H ; スーパーモンク
7FC4: 20 20 JR NZ, .NEXT
.IS_MONK:
7FC6: C5 PUSH BC
7FC7: DD E5 PUSH IX
7FC9: E1 POP HL
7FCA: 11 18 00 LD DE, 0018H ; 武器4スロット先頭
7FCD: 19 ADD HL, DE
7FCE: CD EE 7F CALL 7FEEH ; 装備中フラグ(bit7)検査 (HLは+1CHへ進む)
7FD1: 38 07 JR C, .ARMOR ; 武器装備ありならスキップ
7FD3: DD 7E 26 LD A, (IX+26H) ; 攻撃力 = レベル * 2
7FD6: 87 ADD A, A
7FD7: DD 77 20 LD (IX+20H), A
.ARMOR:
7FDA: CD EE 7F CALL 7FEEH ; 防具4スロット(+1CH..+1FH)のbit7検査
7FDD: 38 06 JR C, .POP_B ; 防具装備ありならスキップ
7FDF: DD 7E 26 LD A, (IX+26H) ; 防御力 = レベル
7FE2: DD 77 22 LD (IX+22H), A
.POP_B:
7FE5: C1 POP BC
.NEXT:
7FE6: 11 40 00 LD DE, 0040H
7FE9: DD 19 ADD IX, DE
7FEB: 10 CE DJNZ .P_LP
7FED: C9 RET
; --- 装備4スロット検査サブルーチン (0x7FEE 〜 0x7FF6: 9バイト) ---
7FEE: 06 04 LD B, 04H ; (.CHK4)
7FF0: AF XOR A
.C_LP:
7FF1: B6 OR (HL)
7FF2: 23 INC HL
7FF3: 10 FC DJNZ .C_LP
7FF5: 07 RLCA ; bit7 (装備中) を Carry へ
7FF6: C9 RET
MENU.COM 装備変更時再計算 (0x8D59, 0x8D95, 0xADBA〜0xADF3)MENU.COM の能力値再計算(0x8D1F)では、「ぶき」「ぼうぐ」画面の終了時に、武器なしなら 0 + (IX+28H)(力/2)、防具なしなら 0 を無条件で書き込んでいました。MENU.COM 末尾の空き領域 0xADBA〜0xADF3(58バイト)に判定サブルーチンを配置し、0x8D59(攻撃力計算)と 0x8D95(防御力計算)から分岐させます。; --- 呼び出し元 ---
8D59: C3 BA AD JP 0ADBAH ; 攻撃力計算フック (+ NOP 7個)
8D95: C3 D9 AD JP 0ADD9H ; 防御力計算フック (+ NOP 4個)
; --- MENU.COM 末尾配置 (0xADBA 〜 0xADF3: 58バイト) ---
ADBA: 3A 44 8D LD A, (8D44H) ; (.MENU_ATK) 武器合計攻撃力
ADBD: B7 OR A
ADBE: 20 0C JR NZ, .W_ADD ; 武器装備ありなら + 力/2 へ
ADC0: DD 7E 00 LD A, (IX+00H) ; ジョブID
ADC3: FE 02 CP 02H ; モンク
ADC5: 28 0C JR Z, .W_MONK
ADC7: FE 08 CP 08H ; スーパーモンク
ADC9: 28 08 JR Z, .W_MONK
ADCB: AF XOR A ; 他ジョブは武器攻撃力 0
ADCC: DD 86 28 ADD A, (IX+28H) ; (.W_ADD) + 力/2
ADCF: DD 77 20 LD (IX+20H), A ; (.W_SET) 攻撃力書き込み
ADD2: C9 RET
ADD3: DD 7E 26 LD A, (IX+26H) ; (.W_MONK) レベル * 2
ADD6: 87 ADD A, A
ADD7: 18 F6 JR .W_SET
ADD9: 3A 44 8D LD A, (8D44H) ; (.MENU_DEF) 防具合計防御力
ADDC: B7 OR A
ADDD: 20 0C JR NZ, .A_SET ; 防具装備ありならそのままセット
ADDF: DD 7E 00 LD A, (IX+00H) ; ジョブID
ADE2: FE 02 CP 02H ; モンク
ADE4: 28 09 JR Z, .A_MONK
ADE6: FE 08 CP 08H ; スーパーモンク
ADE8: 28 05 JR Z, .A_MONK
ADEA: AF XOR A ; 他ジョブは防御力 0
ADEB: DD 77 22 LD (IX+22H), A ; (.A_SET) 防御力書き込み
ADEE: C9 RET
ADEF: DD 7E 26 LD A, (IX+26H) ; (.A_MONK) レベル
ADF2: 18 F7 JR .A_SET
--auto-target)0x36B3〜0x36E6, 52バイト)に本体を配置し、敵リジェネレーション処理やプレイヤー毒2ダメージと両立します。; =============================================================================
; オートターゲット本体サブルーチン (常駐領域B 0x36B3 〜 0x36E6: 52バイト)
; 入力: .XBCD6 (対象スロット番号)
; 出力: .XBCD6 (必要時更新), Carry=0 (正常復帰) / Carry=1 (敵全滅)
; =============================================================================
AUTO_TARGET:
36B3: C5 PUSH BC ; レジスタ退避
36B4: D5 PUSH DE
36B5: E5 PUSH HL
36B6: 3A D6 BC LD A, (.XBCD6) ; 対象スロット取得
36B9: FE 09 CP 09H ; 敵単体スロット (0〜8) か?
36BB: 30 25 JR NC, .EXIT_OK ; 味方や全体なら何もしない (Carry=0)
; 現在の対象敵が生存しているか確認
36BD: 5F LD E, A
36BE: 16 00 LD D, 00H
36C0: 21 66 BC LD HL, 0BC66H ; 敵IDテーブル先頭
36C3: 19 ADD HL, DE
36C4: 7E LD A, (HL)
36C5: FE FF CP 0FFH ; 0xFF (死亡) か?
36C7: 20 19 JR NZ, .EXIT_OK ; 生存中ならそのまま復帰 (Carry=0)
; 死亡しているためスロット0から生存敵を探索
36C9: 21 66 BC LD HL, 0BC66H
36CC: 06 09 LD B, 09H ; 最大9体ループ
36CE: 0E 00 LD C, 00H ; C = スロット番号 (0〜8)
.LOOP:
36D0: 7E LD A, (HL)
36D1: FE FF CP 0FFH
36D3: 20 09 JR NZ, .FOUND ; 生存敵発見
36D5: 23 INC HL
36D6: 0C INC C
36D7: 10 F7 DJNZ .LOOP
; 全員死亡時
36D9: E1 POP HL ; レジスタ復帰
36DA: D1 POP DE
36DB: C1 POP BC
36DC: 37 SCF ; Carry=1 (全滅)
36DD: C9 RET
.FOUND:
36DE: 79 LD A, C ; A = 新スロット番号
36DF: 32 D6 BC LD (.XBCD6), A ; 対象スロット更新
.EXIT_OK:
36E2: E1 POP HL ; レジスタ復帰
36E3: D1 POP DE
36E4: C1 POP BC
36E5: B7 OR A ; Carry=0 (正常)
36E6: C9 RET
SUB05.MAP)において、泉の南側水際マスに会話メッセージ判定(メッセージ 0xF7:「すきとおった みずが わきでている」)を持つタイル 0x3B (59) ではなく通常タイルが配置されていたため、調べても何も反応しませんでした。0x00〜0x7F): 単一タイルID0x80〜0xFE): タイルID = (バイト値 & 0x7F)、次バイト = 連続数(0なら256)0xFF: 終端マーカーSUB05.MAP の圧縮ストリームを 4,096 バイトの平文タイル配列へ展開します。0x3B (59) に置換します。0xFF を付加します。0x00 でパディングして書き戻します。MENU.COM: 0x9CA4)では、最大MPから現在MPへの回復を行った後にセーブ確認へ進みます。しかしメッセージ本文がFC版のまま「HPかいふく!セーブしてまほうかいふくもする?」となっており、実際の動作順と文面が一致していませんでした。MENU.COM 内のオフセット 0x26A5〜0x2DB8(RAM 0xA6A5〜0xADB8)に MENU.MSG と同一のメッセージデータが埋め込まれており、MENU.COM のメッセージ表示処理は LD IX, 0A6A5H により内部埋め込み領域を直接参照しています。HPとまほうをかいふくしました!セーブもする?」へ置換します(2行目「 えーぼたん‥‥はい びーぼたん‥‥いいえ」および終端 0x00 を含む全47 Byte枠のサイズは不変のため、後続データのオフセットは変化しません)。MENU.COM(オフセット 0x29D7 / RAM 0xA9D7)と、ディスク上の独立ファイル MENU.MSG(オフセット 0x0332)の双方を書き換えます。変更前 (23 Byte): C8 C9 8F 8B A5 91 C4 D7 C2 6D 95 9C A8 A7 8C 8F 8B A5 91 AC 96 B2 C5
(HPかいふく!セーブしてまほうかいふくもする?)
変更後 (23 Byte): C8 C9 9D A8 A7 8C 7B 8F 8B A5 91 95 A8 95 99 C4 D7 C2 6D AC 96 B2 C5
(HPとまほうをかいふくしました!セーブもする?)
0x8019) は、BIOS の SNSMAT (0x0141) でキーマトリクス行6を読み、CTRLキーが押されているかで起動を続けるかを決めています。これは、電源投入時に CTRL を押して1ドライブシミュレーションを無効化し、フリーエリアを確保することの代用判定です。0xDE62 付近まで下がります。ディスクのブート処理は HIMEM の 0x1E6 下付近に BIOS エントリから呼ばれるルーチンと一時SPエリアを置くため、その常駐が 0xDC5C 付近まで下り、ゲームが起動時に MAIN.COM (0x447B) で行う 0xDC00〜0xDC7F の0クリアと重なります。クリアで常駐の下側が消え、ゲーム中にそのルーチンが呼ばれた時点で動作が止まります。0xFC4A) の直接確認へ置換します。必要な値は、クリア範囲の上限 0xDC80 にブート処理の常駐分 0x1E6 を加えた 0xDE86 です。00 で埋めます。0x8019 のルーチンを、BDOS _LOGIN のログインベクタで有効ドライブが1台かを見る判定へ置き換えているため、置換前のバイト列として製品版と Performance Patch 版の両方を受け付けます。併用する場合は Performance Patch を先に適用してから本スクリプトを実行してください。Performance Patch の IPS は元のバイトを確認せずに上書きするため、後から適用するとフリーエリア判定が消えてログインベクタ判定に戻ります。なお、ログインベクタ判定はドライブの台数を見るもので、フリーエリアの大きさ自体は確認していません。変更前 (33 Byte): 3E 06 DD E5 FD E5 FD 2A C0 FC DD 21 41 01 CD 1C 00 FD E1 DD E1 CB 4F C8 21 3A 80 CD D9 80 C3 6D 81
LD A,06H で SNSMAT (0x0141) を呼び行6を読み、CTRL (Bit 1) が押されていれば RET、
なければメッセージ (0x803A) を表示して停止 (0x816D) へ
変更後 (33 Byte): 2A 4A FC 11 86 DE B7 ED 52 D0 21 3A 80 CD D9 80 C3 6D 81 00 00 00 00 00 00 00 00 00 00 00 00 00 00
LD HL,(0xFC4A) / LD DE,0xDE86 / OR A / SBC HL,DE / RET NC で、HIMEM が 0xDE86 以上なら起動を継続、
なければ LD HL,0x803A / CALL 0x80D9 / JP 0x816D で元のメッセージ表示後に停止 (残り14 Byte は 00)
SMAP.COM)、河川進入判定(MAIN.COM)、重要品一覧展開(MENU.COM)のすべてが同一のメモリ番地 0xC210 を参照・更新するように設計されています。FC版のようなフラグ不整合は発生しないため、対応不要です。0xC120〜 が「現在MP」、0xC128〜 が「最大MP」となっており、コテージ使用処理(MENU.COM: 0x9CA4)では最大MPから現在MPへの全回復コピーが正しく行われています。EXDATA1.COM 0x0070〜)ではタイル座標 X=30 (0x1E), Y=11 (0x0B) に配置されており、属性フラグ領域(+0x08, +0x09)も 0x00(室外)で初期化されています。MSX2版はビットマップ画面(SCREEN 5)で一枚絵として描画しており、常時正常に表示されるためバグは存在しません。0x24 / EXDATA2.COM 0x0400〜)にはロボット1体のみが配置されており、コウモリNPC自体が存在しません。0x08)やアースの洞窟B3(マップ 0x12)の別マップNPCを指していたため、パッチ対象から除外(対応不要)と整理しました。SMAP.COM):
0x97EE / NPC ID 0x99)がすでに正しい水のオーブ(0xC212)を参照しており、バグは存在しません。(0x9448 / NPC ID 0x5D はドワーフの洞窟の住民であり、正常な土のオーブ 0xC214 を参照しています)94/9D 担当の賢者に相当する MSX2版のNPC(0x96EF / NPC ID 0x7E)には、すでに4オーブ全点灯の判定が実装済みです。(0x971B / NPC ID 0x7F は土のオーブ点灯後〜火のオーブ点灯前のみ専用ヒント 0x95 を話す別の賢者です)0x8077)は、CP 0AH と CP 02H のみを除外するコードへ書き直されており、4つの祭壇すべてを通過します。また、SUBx.CHR は FC版と同一データであり祭壇タイルにテレポート用の 0x40 ビットは付かないため、SMAP.COM に対する修正は不要です。SUB05.MAP のガイアの妖精の泉タイル復元)のみ です。0xDC4E、起動時クリアは 0xDC00〜0xDC7F (MAIN.COM 0x447B)、スタックポインタは 0xD900 固定です。0x1E6 下に置かれる構成では、HIMEM が 0xDE86 未満だとクリア範囲と常駐が重なるため、パッチ17 で HIMEM の直接判定へ置換しました。